MQTT temelleri: broker, konular ve jokerler

#include <WiFi.h>
#include <PubSubClient.h>
#include "secrets.h"                     // WIFI_SSID, WIFI_PASS, MQTT_HOST

WiFiClient net;
PubSubClient mqtt(net);
const char* ID = "sera-01";              // broker'da benzersiz olmalı
uint32_t lastPub = 0, nextTry = 0;

void onMessage(char* topic, byte* payload, unsigned int len) {
  String msg((char*)payload, len);
  if (String(topic) == "sera/01/led/set") digitalWrite(2, msg == "1");
}

void mqttTask() {
  if (mqtt.connected()) { mqtt.loop(); return; }   // loop() gelen mesajları ve PING'i işler
  if (millis() < nextTry) return;
  if (mqtt.connect(ID)) mqtt.subscribe("sera/01/+/set");
  else nextTry = millis() + 5000;                   // bloklamadan sonra yeniden dene
}

void setup() {
  pinMode(2, OUTPUT);
  WiFi.begin(WIFI_SSID, WIFI_PASS);
  mqtt.setServer(MQTT_HOST, 1883);                  // 1883 açık metin; gerçek kurulumda 8883 + TLS
  mqtt.setCallback(onMessage);
}

void loop() {
  if (WiFi.status() != WL_CONNECTED) return;
  mqttTask();
  if (mqtt.connected() && millis() - lastPub > 10000) {
    lastPub = millis();
    mqtt.publish("sera/01/sicaklik", String(temperatureRead(), 1).c_str());  // çip sıcaklığı; DHT22 sonraki ünitelerde
  }
}

from umqtt.simple import MQTTClient
from machine import Pin
import time, esp32
from secrets import MQTT_HOST

led = Pin(2, Pin.OUT)

def on_msg(topic, msg):                  # konu ve yük bytes olarak gelir
    if topic == b'sera/01/led/set':
        led.value(msg == b'1')

c = MQTTClient('sera-01', MQTT_HOST, keepalive=30)
c.set_callback(on_msg)
c.connect()
c.subscribe(b'sera/01/+/set')            # + tek seviye: led/set, fan/set…

last = 0
while True:
    c.check_msg()                        # bloklamaz; bekleyen mesaj varsa on_msg çağrılır
    if time.ticks_diff(time.ticks_ms(), last) > 10000:
        last = time.ticks_ms()
        t = (esp32.raw_temperature() - 32) / 1.8
        c.publish(b'sera/01/sicaklik', str(round(t, 1)))
    time.sleep_ms(50)